Specification before use

To allow compiling in one pass ALGOL 68-R insisted that all identifiers were specified (declared) before use.

The standard program:

PROC even = (INT number) BOOL: ( number = 0 | TRUE | odd (ABS (number - 1)));
PROC odd = (INT number) BOOL: ( number = 0 | FALSE | even (ABS (number - 1)));

would have to be rewritten as:

PROC (INT) BOOL odd;
PROC even = (INT number) BOOL : ( number = 0 | TRUE | odd (ABS (number - 1)));
odd := (INT number) BOOL : ( number = 0 | FALSE | even (ABS (number - 1)));

To allow recursive declarations of modes (types) a special stub mode declaration was used to inform the compiler that an up-coming symbol was a mode rather than an operator:

MODE B;
MODE A = STRUCT (REF B b);
MODE B = [1:10] REF A;

No proceduring

In the standard language the proceduring coercion could, in a strong context, convert an expression of some type into a procedure returning that type. This could be used to implement call by name.

Another case where proceduring was used was the declaration of procedures, in the declaration:

PROC x plus 1 = INT : x + 1;

the right hand side was a cast of x + 1 to integer, which was then converted to procedure returning integer.

The ALGOL 68-R team found this too difficult to handle and made two changes to the language. The proceduring coercion was dropped, and the form mode : expression was redefined as a procedure denotation, casts being indicated by an explicit VAL symbol:

REAL : x     CO a cast to REAL in ALGOL 68 CO

REAL VAL x   CO a cast to REAL in ALGOL 68-R CO

Code that had a valid use for call by name (for example, Jensen's device) could simply pass a procedure denotation:

 PROC sum = (INT lo, hi, PROC (INT) REAL term) REAL :
 BEGIN
    REAL temp := 0;
    FOR i FROM lo TO hi DO
       temp +:= term (i);
    temp
 END;
 print (sum (1, 100, (INT i) REAL: 1/i))

In the version of the language defined in the revised report these changes were accepted, although the form of the cast was slightly changed to mode (expression).

REAL (x)      CO a cast to REAL in revised ALGOL 68 CO

Explicit void mode

In the original language the VOID mode was represented by an empty mode:

: x := 3.14;            CO cast (x := 3.14) to void CO

PROC endit = GOTO end;  CO a procedure returning void CO

The ALGOL 68-R team decided to use an explicit VOID symbol in order to simplify parsing (and increase readability):

VOID VAL x := 3.14;            CO cast (x := 3.14) to void CO

PROC endit = VOID : GOTO end;  CO a procedure returning void CO

This modification to the language was adopted by the ALGOL 68 revised report.

No formal declarers

Formal declarers are the modes on the left hand side of an identity declaration, or the modes specified in a procedure declaration. In the original language, they could include array bounds and specified whether the matching actual declarer was fixed, FLEX or EITHER:

[ 15 ] INT a;                    CO an actual declarer, bounds 1:15 CO
REF [ 3 : ] INT b = a;           CO This is an error CO

PROC x = (REF [ 1 : EITHER] INT a) : ...

I think it was a reasonable thing myself to omit the bounds from the formal-declarers but I think it was a terrible crime to omit the EITHER or the FLEX
– Lindsey^[8]

The ALGOL 68-R team redefined formal declarers to be the same as virtual declarers which include no bound information. They found that this reduced the ambiguities in parsing the language and felt that it was not a feature that would be used in working programs.

If a procedure needed certain bounds for its arguments it could check them itself with the UPB (upper bound) and LWB (lower bound) operators.

In ALGOL 68-R the example above could be recoded like this: (the bounds of a in the procedure would depend on the caller).

[ 15 ] INT a;                    CO an actual declarer, bounds 1:15 CO
REF [] INT b = a [ AT 3];        CO use slice so b has bounds 3:17 CO

PROC x = (REF [] INT a) VOID: ...   CO bounds given by caller CO

In the revised report on ALGOL 68 formal bounds were also removed, but the FLEX indication was moved in position so it could be include in formal declarers:

[ 1: FLEX ] INT a;      CO original ALGOL 68, or ALGOL 68-R CO
FLEX [ 1: ] INT a;      CO revised ALGOL 68, CO

PROC x = (REF [ 1: FLEX ] INT a) : ...  CO Original ALGOL 68 CO
PROC x = (REF [ ] INT a) VOID: ...      CO ALGOL 68-R CO
PROC x = (REF FLEX [ ] INT a) VOID: ... CO Revised ALGOL 68 CO

No parallel processing

In ALGOL 68 code can be run in parallel by writing PAR followed by a collateral clause, for example in:

PAR BEGIN
   producer,
   consumer
END

the procedures producer and consumer will be run in parallel. A semaphore type (SEMA) with the traditional P (DOWN) and V (UP) operators is provided for sysynchronizing between the parts of the parallel clause,

This feature was not implemented in ALGOL 68-R.

An extension named ALGOL 68-RT was written which used the subprogramming feature of the ICL 1900 to provide multithreading facilities to ALGOL 68-R programs with semantics similar to modern thread libraries.^[9] No changes were made to the compiler, only the runtime library and the linker.

goto may not be omitted

In ALGOL 68 the GOTO symbol could be omitted from a jump:

PROC stop = : ...;

...

BEGIN
   IF x > 3 THEN stop FI;  CO a jump, not a call CO
   ...
stop:
   SKIP
END

As ALGOL 68-R was a one pass compiler this was too difficult, so the GOTO symbol was made obligatory.

The same restriction was made in the official sublanguage, ALGOL 68S.^[10]

Uniting is only allowed in strong positions

In ALGOL 68 uniting is the coercion that produces a UNION from a constituent mode, for example:

MODE IBOOL = UNION (INT, BOOL);    CO an IBOOL is an INT or a BOOL CO
IBOOL a = TRUE;       CO the BOOL value TRUE is united to an IBOOL CO

In standard ALGOL 68 uniting was possible in firm or strong contexts, so for example could be applied to the operands of formulas:

 OP ISTRUE = (IBOOL a) BOOL: ...;
 IF ISTRUE 1               CO legal because 1 (INT) can be united to IBOOL CO
 THEN ...

The ALGOL 68-R implementers found this gave too many ambiguous situations so restricted the uniting coercion to strong contexts.

The effects of this restriction were rarely important and, if necessary, could be worked around by using a cast to provide a strong context at the required point in the program.

Separate compiling

Since ALGOL 68 is a strongly typed language, the simple library facilities used by other languages on the ICL 1900 system were insufficient. ALGOL 68-R was delivered with its own library format and utilities which allowed sharing of modes, functions, variables, and operators between separately compiled segments of code which could be stored in albums.^[14]

A segment to be made available to other segments would end with a list of declarations to be made available:

graphlib             CO the segment name CO
BEGIN
   MODE GRAPHDATA = STRUCT ( ... );
   MODE GRAPH = REF GRAPHDATA;
   PROC new graph = ( ... ) GRAPH : ...;
   PROC draw graph = (GRAPH g) VOID : ...;
   ...
END
KEEP GRAPH, new graph, draw graph
FINISH

And then the graph functions could be used by another segment:

myprog WITH graphlib FROM graphalbum
BEGIN
    GRAPH g = new graph (...);
    ...
    draw graph (g);
    ...
END
FINISH

Low level system access

As a strongly typed high level language, ALGOL 68 prevents programs from directly accessing the low level hardware. No operators exist for address arithmetic, for example.

Since ALGOL 68-R didn't compile to standard ICL semicompiled (link-ready) format, it was necessary to extend the language to provide features in ALGOL 68-R to write code that would normally be written in assembly language. Machine instructions could be written inline, inside CODE ... EDOC sections and the address manipulation operators INC, DEC, DIF, AS were added.^[15]

An example, using a George peri operation to issue a command:

[1 : 120] CHAR buff;
INT unitnumber;
STRUCT (BITS typemode, reply, INT count, REF CHAR address)
      control area := (8r47400014,0,120,buff[1]);
...;
CODE 0,6/unitnumber; 157,6/typemode OF control area EDOC